# -*- coding: utf-8; mode: tcl; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- vim:fenc=utf-8:filetype=tcl:et:sw=4:ts=4:sts=4

PortSystem          1.0
PortGroup           gitlab 1.0
PortGroup           gobject_introspection 1.0

name                librsvg-devel
set my_name         librsvg
conflicts           librsvg

categories          graphics gnome
license             {GPL-2+ LGPL-2+}
maintainers         {mascguy @mascguy} openmaintainer
description         GNOME implementation of rsvg.
long_description    {*}${description}

depends_build-append \
                    path:bin/pkg-config:pkgconfig \
                    path:bin/vala:vala

depends_lib-append \
                    path:lib/pkgconfig/cairo.pc:cairo \
                    port:fontconfig \
                    path:lib/pkgconfig/gdk-pixbuf-2.0.pc:gdk-pixbuf2 \
                    port:gettext-runtime \
                    path:lib/pkgconfig/glib-2.0.pc:glib2 \
                    path:lib/pkgconfig/harfbuzz.pc:harfbuzz \
                    port:libiconv \
                    port:libxml2 \
                    path:lib/pkgconfig/pango.pc:pango

license_noconflict \
                    gobject-introspection \
                    rust \
                    vala

# https://trac.macports.org/ticket/70693
# new releases of librsvg depend on cargo and its libraries,
# which became unbuildable on macOS <10.7
set min_darwin_for_rust 11

#----------------------------------------------------------------------------------------
# Developer-only override, allowing easy testing of desired behavior:
# - librsvg.override.fallback=yes - Force use of fallback release
# - librsvg.override.fallback=no  - Force use of latest release
#----------------------------------------------------------------------------------------
if {[info exists librsvg.override.fallback]} {
    if {[string is boolean -strict ${librsvg.override.fallback}]} {
        ui_msg "librsvg.override.fallback specified: ${librsvg.override.fallback}"
        set librsvg_fallback \
            [string is true -strict ${librsvg.override.fallback}]
    } else {
        error "librsvg.override.fallback must be specified as a valid boolean value"
    }
} else {
    if {${os.platform} eq "darwin" && (
            ${os.major} < ${min_darwin_for_rust}
            || ${configure.build_arch} in "ppc ppc64"
            || ${universal_possible} && [variant_isset universal] && ("ppc" in ${configure.universal_archs} || "ppc64" in ${configure.universal_archs})
        )} {
        set librsvg_fallback yes
    } else {
        set librsvg_fallback no
    }
}

if {${librsvg_fallback}} {
    # revert to latest pre-cargo version
    version         2.40.21
    revision        1
    epoch           1

    checksums       rmd160  5135ad75e976658936d03655faa37f9ed1c11a3e \
                    sha256  f7628905f1cada84e87e2b14883ed57d8094dca3281d5bcb24ece4279e9a92ba \
                    size    1655860

    # https://trac.macports.org/ticket/65407
    patchfiles-append \
                    patch-librsvg-makefile-in-vapi-deps.diff

    patchfiles-append \
                    patch-libxml2-2.14.6.diff

    # pre-cargo versions still use libcroco
    depends_lib-append \
                    port:libcroco

    # variant viewer disabled by default in an attempt to avoid loading
    # gtk3 by those who are using it strictly as a library outside of GTK+/GNOME.
    # https://trac.macports.org/ticket/43328
    # https://trac.macports.org/ticket/47443
    # https://trac.macports.org/ticket/47596
    variant viewer description "Build the rsvg-view-3 viewer utility." {
        depends_lib-append  path:lib/pkgconfig/gtk+-3.0.pc:gtk3
        depends_run-append  port:adwaita-icon-theme
    }
    if {![variant_isset viewer]} {
        patchfiles-append   patch-disable-viewer-pre-cargo.diff
    }

    configure.args-append \
                    --disable-Bsymbolic \
                    --disable-gtk-doc \
                    --disable-installed-tests \
                    --disable-always-build-tests \
                    --disable-silent-rules \
                    --enable-introspection=yes \
                    --enable-vala=yes

    variant tests description {Enable tests} {
        configure.args-replace \
                    --disable-installed-tests \
                    --enable-installed-tests
        configure.args-replace \
                    --disable-always-build-tests \
                    --enable-always-build-tests

        test.run    yes
        test.dir    ${worksrcpath}/tests
        test.target check
    }
} else {
    PortGroup       meson 1.0

    version         2.63.4
    revision        1
    epoch           2

    checksums       rmd160  50f7c6276c59331274d9ff129d4e9728423ab292 \
                    sha256  a22fc1a804424d87bdeaeef96e948c2a880c17ac48eade874ae9ca8e567e84ed \
                    size    7678368

    # Disable unexpected download of subprojects
    meson.wrap_mode nodownload

    # Patch to properly set dylib versions; will eventually be contributed to upstream
    patchfiles-append \
                    patch-meson-dylib-versions.diff

    depends_build-append \
                    port:cargo \
                    port:cargo-c \
                    port:python314

    depends_lib-append \
                    port:dav1d \
                    port:freetype \
                    port:libpng \
                    port:zlib

    if {${os.platform} eq "darwin" && ${os.major} < 20} {
        depends_build-append port:cctools
        configure.env-append NM=${prefix}/bin/nm
    }

    meson.native.binaries   python=${prefix}/bin/python3.14

    compiler.c_standard 2011

    configure.args-append \
                    -Davif=enabled \
                    -Ddocs=disabled \
                    -Dpixbuf=enabled \
                    -Dtests=false \
                    -Dvala=enabled

    variant tests description {Enable tests} {
        configure.args-replace \
                    -Dtests=false \
                    -Dtests=true

        test.run        yes
    }
}

gitlab.instance     https://gitlab.gnome.org
gitlab.setup        GNOME librsvg ${version}
distname            ${my_name}-${version}
dist_subdir         ${my_name}
if {${librsvg_fallback}} {
    use_xz          yes
}

gobject_introspection yes

post-destroot {
    set docdir ${prefix}/share/doc/${name}
    xinstall -d ${destroot}${docdir}
    xinstall -m 644 -W ${worksrcpath} AUTHORS COPYING.LIB \
        ${destroot}${docdir}

    if {${librsvg_fallback}} {
        xinstall -m 644 -W ${worksrcpath} COPYING \
            ${destroot}${docdir}
    }

    xinstall -m 755 -W ${filespath} svg2pdf \
        ${destroot}${prefix}/bin

    set badfile ${prefix}/lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-svg.a
    if {[file exists ${destroot}${badfile}]} {
        file delete ${destroot}${badfile}
    }
}

post-activate {
    system "${prefix}/bin/gdk-pixbuf-query-loaders --update-cache"
}

post-deactivate {
    system "${prefix}/bin/gdk-pixbuf-query-loaders --update-cache"
}

gitlab.livecheck.regex {(\d+(?:\.\d+)*)}
