ເນື້ອໃນ

# ຟັງຊັນ CreateUnoServiceWithArguments

ສ້າງອິນສະແຕນຊ໌ຂອງບໍລິການ UNO ດ້ວຍ ProcessServiceManager, ລວມທັງອາກິວເມັນເສີມທີ່ເລືອກໄດ້.

### ໄວຍາກອນ:

        CreateUnoServiceWithArguments(ServiceName As String, Arguments() As Variant) As Object

ບໍລິການ UNO ທີ່ສາມາດໃຊ້ກັບຟັງຊັນ CreateUnoServiceWithArguments ສາມາດສັງເກດໄດ້ຈາກຊື່ເມທອດທີ່ຂຶ້ນຕົ້ນດ້ວຍ createInstanceWith.. ຫຼື createWith...

### ປະເພດຄ່າທີ່ສົ່ງກັບ:

ວັດຖຸ

ສຳລັບລາຍການບໍລິການທີ່ມີຢູ່, ສາມາດເບິ່ງໄດ້ທີ່ໜ້າອ້າງອີງ ໂມດູນ com::sun::star.

### ພາຣາມິເຕີ:

ຊື່ | ປະເພດ | ຄຳອະທິບາຍ
--- | --- | ---
ຊື່ບໍລິການ (ServiceName) | String | ຊື່ຂອງບໍລິການ UNO ທີ່ຈະສ້າງ.
ອາກິວເມັນ (Arguments) | Variant | ອາກິວເມັນໜຶ່ງ ຫຼື ຫຼາຍໂຕ ທີ່ກຳນົດລາຍລະອຽດຂອງອິນສະແຕນຊ໌ບໍລິການ. ອາກິວເມັນ ຈະຖືກເກັບໄວ້ໃນຮູບແບບອາເຣມິຕິດຽວ (one dimensional array), ຕາມຕຳແໜ່ງທີ່ກຳນົດໄວ້ໃນເມທອດຄອນສະຕຣັກເຕີ (constructor method).

### ຕົວຢ່າງ:

ຕົວຢ່າງ com.sun.star.ui.dialogs.FilePicker ດ້ານລຸ່ມຈະສະແດງກ່ອງໂຕ້ຕອບ ບັນທຶກເປັນ (Save As) ຂອງ LibreOffice ພ້ອມກັບຕົວຄວບຄຸມເພີ່ມເຕີມສອງຢ່າງຄື: ລາຍການເລືອກ (listbox) ແລະ ຊ່ອງໝາຍ (checkbox).

        Sub FileSaveAsDialog()
           td = com.sun.star.ui.dialogs.TemplateDescription
           options = td.FILESAVE_AUTOEXTENSION_TEMPLATE
           dlg = CreateUnoServiceWithArguments( _
              "com.sun.star.ui.dialogs.FilePicker", _
              Array(options))
           dlg.execute()
        End Sub ' FileSaveAsDialog

ໄດອາລັອກໄຟລ໌ - ເຊັ່ນ ເປີດ, ບັນທຶກເປັນ, ແຊກຂໍ້ຄວາມ ແລະ ອື່ນໆ - ມີໃຫ້ໃຊ້ໃນສອງຮູບແບບ:

- ເປັນໄດອາລັອກເລືອກໄຟລ໌ມາດຕະຖານຂອງລະບົບປະຕິບັດການຂອງທ່ານ.

- ເປັນໄດອາລັອກເລືອກໄຟລ໌ທີ່ມາພ້ອມກັບ LibreOffice.

ໃຊ້ LibreOffice - ຄວາມມັກເຄື່ອງມື - ຕົວເລືອກ - LibreOffice - ທົ່ວໄປ ເພື່ອປ່ຽນຈາກແບບໜຶ່ງໄປຫາອີກແບບໜຶ່ງ.

ບໍລິການ UNO ມີເອກະສານອອນໄລນ໌ຢ່າງລະອຽດຢູ່ທີ່ເວັບໄຊ api.libreoffice.org. ສາມາດເຂົ້າເບິ່ງໜ້າອ້າງອີງ ບໍລິການ FilePicker ເພື່ອສຶກສາເພີ່ມເຕີມກ່ຽວກັບເມທອດຕ່າງໆທີ່ບໍລິການນີ້ມີໃຫ້ໃນຕົວຢ່າງຂ້າງເທິງ.

### ຕົວຢ່າງ:

ໂຄ້ດຕໍ່ໄປນີ້ໃຊ້ບໍລິການ com.sun.star.security.DocumentDigitalSignatures ເພື່ອເຊັນເອກະສານປັດຈຸບັນດ້ວຍລາຍເຊັນດິຈິຕອນ:

    Sub  SignCurrentDocDialog
       Dim pv(0) as new com.sun.star.beans.PropertyValue
       pv(0).Name  = "StorageFormat"
       pv(0).Value = "ZipFormat"
       mode = com.sun.star.embed.ElementModes
       sf = CreateUnoService("com.sun.star.embed.StorageFactory")
       storage = sf.createInstanceWithArguments(Array(ThisComponent.URL, mode.WRITE, pv))
       dds = CreateUnoServiceWithArguments( _
          "com.sun.star.security.DocumentDigitalSignatures", _
          Array("1.2", True))
       dds.signDocumentContent(storage, Null)
    End Sub ' SignCurrentDocDialog

ເມທອດຄອນສະຕຣັກເຕີ CreateWithVersion ແລະ createWithVersionAndValidSignature ໃນບໍລິການ UNO com.sun.star.security.DocumentDigitalSignatures ສະແດງໃຫ້ເຫັນເຖິງສອງວິທີທີ່ແຕກຕ່າງກັນໃນການສ້າງອິນສະແຕນຊ໌ບໍລິການນີ້ດ້ວຍຟັງຊັນ CreateUnoServiceWithArguments.

ຫົວຂໍ້ທີ່ກ່ຽວຂ້ອງ

ຟັງຊັນ CreateUnoService

ອັອບເຈັກ, ຟັງຊັນ ແລະ ບໍລິການຂອງ UNO

ການໃຊ້ຟັງຊັນ Calc ໃນມາກໂຄ

ກະລຸນາສະໜັບສະໜູນພວກເຮົາ!